#! /bin/csh 

if ( ! -d tutorial_disulfide ) mkdir tutorial_disulfide
cd  tutorial_disulfide
cp ../data/1fsc.pdb .

# Demonstrate how to make disulfide bonds in mmtsb tools
#
set pdb=1fsc
set pdb_H=${pdb}_H

# condition the pdb file, add hydrogens, remove hetero atoms and 
# crystal water molecules.
# This protein has 61 residues numbered 1 to 61, the rest is other stuff.
#
     echo -n "converting pdb, adding H,  "
convpdb.pl -out charmm22 -sel 1:61< $pdb.pdb \
       | complete.pl - \
       >! $pdb_H.pdb
     echo "done ($pdb_H.pdb)"
# Use the patch parameter with CHARMM to get an energy of the structure
#  with the disulfide bonds made.
#
     echo -n "Initial Energy:   "
enerCHARMM.pl -par patch=disu:3:22_DISU:17:39_DISU:41:52_disu:53:59 \
              < $pdb_H.pdb
#
# We will use these disulfides for all CHARMM functions so make it
# a variable that is easier to read and type, and avoid typos.
#   (note that patches are not case sensitive)
#
set sspar=disu:3:22_DISU:17:39_DISU:41:52_disu:53:59
#
# Short minimization
#
     echo -n "Minimizing  "
minCHARMM.pl -par patch=$sspar,sdsteps=50,minsteps=50 \
        -log min.log -elog emin.log -cmd min.inp \
        < $pdb_H.pdb \
        >! ${pdb_H}_min.pdb
     echo "done (${pdb_H}_min.pdb)"
     echo -n "Minimized Energy: "
enerCHARMM.pl -par patch=$sspar \
        < ${pdb_H}_min.pdb 


cd ..