* Membrane System : step4.inp
* Assemble each component and minimize & equilibration
*

stream system.str

!Read topologie
open read card unit 10 name @charmmdir/top_all27_prot_lipid.rtf
read  rtf card unit 10

!Read parameters
open read card unit 20 name @charmmdir/par_all27_prot_lipid.prm
read para card unit 20

!Protein
open read card unit 10 name pept.psf
read psf  card unit 10

open read card unit 10 name pept.pdb
read coor pdb  unit 10 resid
close unit 10

!DMPC
open read card unit 10 name step4_dmpc.crd
read sequence coor unit 10
generate DMPC setup first none last none

open read card unit 10 name step4_dmpc.crd
read coor card unit 10 append

!Water
open read card unit 10 name step4_tip3.crd
read sequence coor unit 10
generate BULK setup noangle nodihedrals

open read card unit 10 name step4_tip3.crd
read coor card unit 10 append

!Image Setup
crystal define tetragonal @BoxsizeXY @BoxsizeXY @BoxsizeZ 90.00 90.00 90.00

open read unit 10 card name box_image.str
crystal read unit 10 card
close unit 10

image byresid xcen 0.0 ycen 0.0 zcen 0.0 sele resname TIP3 .or. resname DMPC end

!setup nonbond option
NBONDS  ATOM  FSHIFT CDIE  VDW VSHIFT  -
        CUTNB 14.0  CTOFNB 11.0 CTONNB 10.0 inbfrq -1 imgfrq -1

ENERGY


!Restrain Potentials
define PEPT sele segid PRO0 end
define HEAD sele ( type P .or. type N  .or. type C1* .or. type O1* ) .and. segid DMPC end

set pforce =  0.0
set wforce =  1.0
set tforce =  0.5
set mforce =  0.5
stream restraint.str

cons fix sele segid PRO0 end


!Minimization
mini sd   nstep 50    nprint 10
mini abnr nstep 50    nprint 10
mini sd   nstep 50    nprint 10
mini abnr nstep 50    nprint 10
mini sd   nstep 50    nprint 10
mini abnr nstep 50    nprint 10
mini sd   nstep 50    nprint 10
mini abnr nstep 50    nprint 10


!Short Langevin Dynamics (NVT) 

scalar fbeta set  10.0 select all end

DYNAMICS  start       nstep   1000  timestp  0.001 iprfrq   1000  nprint 100  -
          iasvel    1 firstt 300.0  finalt   300.0 tstruc  300.0  -
          langevin    tbath  300.0  rbuf       0.0 -
          inbfrq   -1 imgfrq    -1  ihbfrq       0 ilbfrq      0  -
          iunread  -1  -
          iunwrite -1  -
          iuncrd   -1 nsavcrd    0  -
          iunvelo  -1 nsavvelo   0  -
          kunit    -1  

open write card unit 1 name system.psf
write  psf card unit 1

open write card unit 1 name step5.pdb
write coor pdb  unit 1

open write card unit 1 name step5.crd
write coor card unit 1

stop