* Restraint Potentials
*

! keep the peptides close to the original positions
if pforce .ne. 0.0 cons harm force @pforce sele .not. hydrogen .and. PEPT end

! keep the water molecules away from the hydrophobic core
MMFP
GEO  plane -
     xref 0.0 yref 0.0 zref 0.0 zdir 1.0 -
     harmonic outside force @wforce droff 9.0 select type OH2 end
END

! keep the lipid tail below +/- 5.0
MMFP
GEO  plane -
     xref 0.0 yref 0.0 zref 0.0 zdir 1.0 -
     harmonic inside  force @tforce droff 5.0 select type C214 .or. type C314 end
END

! keep the lipid head groups close to target values
set i 1
calc ntop = 0
calc nbot = 0
label DOMMFP

   coor stat mass select ( HEAD .and. resi @i ) end
   if ?zave gt 0 then 
      MMFP
      GEO plane  RCM -
          xref 0.0  yref 0.0  zref  17.0   zdir 1.0 -
          force  @mforce   select HEAD .and. resi @i end
      END
      calc ntop = @ntop + 1
   endif
   if ?zave le 0 then
      MMFP
      GEO plane  RCM -
          xref 0.0  yref 0.0  zref -17.0   zdir 1.0 -
          force  @mforce   select HEAD .and. resi @i end
      END
      calc nbot = @nbot + 1
   endif

incr i by 1
if i le @Nlipid goto DOMMFP
calc ntot = @nbot + @ntop