* WALP16 Generation
*

set charmmdir = .

!Read topologie
open read card unit 10 name @charmmdir/top_all27_prot_lipid.rtf"
read  rtf card unit 10

!Read parameters
open read card unit 20 name @charmmdir/par_all27_prot_lipid.prm
read para card unit 20

read sequence card
* sequence of WALP16
*
 16
! 1   2   3   4   5   6   7   8   9  10
 GLY TRP TRP LEU ALA LEU ALA LEU ALA LEU 
 ALA LEU ALA TRP TRP ALA

generate PRO0 setup first ACE last CT3

coor stat select type CA end
set ntot = ?nsel

set i = 1
label ic_edit

calc j = @i - 1
calc k = @i + 1

if j .ge.  1 then
IC EDIT
DIHE @j  C  @i  N  @i CA  @i  C -57.8  ! PHI
END
endif

if k .le. @ntot then
IC EDIT
DIHE @i  N  @i CA  @i  C  @k  N -47.0  ! PSI
END
endif

incr i by 1
if i .le. @ntot goto ic_edit

ic param
ic seed 1 N 1 CA 1 C
ic build

hbuild

NBOND atom switch cdie vdw vswitch bycb -
      ctonnb 20.0 ctofnb 20.0 cutnb 24.0

mini   sd nstep  50 nprint 10 step 0.005 inbfrq -1 imgfrq -1
mini abnr nstep  50 nprint 10 step 0.005 inbfrq -1 imgfrq -1

coor stat
coor orie
coor stat
coor rotate ydir  1.0 phi 90.0
coor stat

open write card unit 10 name pept.pdb
write coor pdb  unit 10
close unit 10

open write card unit 10 name pept.psf
write psf  card unit 10
close unit 10

stop