* Membrane System : equi1.inp
* System equilibration with CPTA dynamics with PME and restraints
*

stream system.str

!Read topologie
open read card unit 10 name @charmmdir/top_all27_prot_lipid.rtf
read  rtf card unit 10

!Read parameters
open read card unit 20 name @charmmdir/par_all27_prot_lipid.prm
read para card unit 20

!System
open read card unit 10 name system.psf
read psf  card unit 10

open read card unit 10 name step5.crd
read coor card unit 10 
close unit 10

!Image Setup
crystal define tetragonal @BoxsizeXY @BoxsizeXY @BoxsizeZ 90.00 90.00 90.00

open read unit 10 card name box_image.str
crystal read unit 10 card
close unit 10

image byresid xcen 0.0 ycen 0.0 zcen 0.0 sele resname TIP3 .or. resname DMPC end

!setup nonbond option
nbonded  atom vatom vswitch bycb -
         ctonnb 11.0 ctofnb 12.0 cutnb 16.0 cutim 16.0 -
         inbfrq -1 imgfrq -1 wmin 1.0 cdie eps 1.0 -
         ewald pmew fftx 64 ffty 64 fftz 64  kappa .34 spline order 6

ENERGY

!setup Restrains
define PEPT sele segid PRO0 end
define HEAD sele ( type P .or. type N  .or. type C1* .or. type O1* ) .and. segid DMPC end

set pforce = 20.0
set wforce =  1.0
set tforce =  0.5
set mforce =  0.5
stream restraint.str


!CPTA Dynamics
open write unit 12 card name equi1.rst

dyna cpt start nstep 1000 timestep 0.002 echeck 9999. -
     pcons pint pref 1.0 pmxx 0. pmyy 0. pmzz 2000. pgamma 0.0 -
     hoover reft 303.15 tmass 20000. -
     iprfrq 5000 ihtfrq 0 ieqfrq 0 ntrfrq 5000 -
     iunrea -1 iunwri 12 iuncrd -1 kunit -1 -
     nprint 100 nsavc 100 nsavv 0 ihbfrq 0 ilbfrq 0 -
     firstt 303.15 finalt 303.15 teminc 10.0 tstruct 303.15 tbath 303.15 -
     iasors 1 iasvel 1 iscvel 0 ichecw 0 twindh 5.0 twindl -5.0

open write unit 10 card name equi1.crd
write coor card unit 10

stop